# Maintainer (aur): Roshless <pkg@roshless.com>
# Maintainer: Iván Ávalos <avalos@disroot.org>

pkgname=lagrange
pkgrel=1
pkgver=1.6.2
pkgdesc="Beautiful Gemini Client"
url="https://gmi.skyjake.fi/lagrange/"
arch=('x86_64' 'i686' 'aarch64' 'armv7h')
license=("BSD2")
source=(
    "https://git.skyjake.fi/skyjake/$pkgname/releases/download/v$pkgver/lagrange-$pkgver.tar.gz"
)
depends=(
    "fribidi"
    "harfbuzz"
    "hicolor-icon-theme"
    "libunistring"
    "openssl"
    "pcre"
    "sdl2"
)
optdepends=("mpg123")
makedepends=("cmake")

prepare() {
  cd "$srcdir"/$pkgname-$pkgver

  # delete vendored libs - use system libs instead
  rm -rf lib/fribidi/
  rm -rf lib/harfbuzz/
}

build() {
    cmake -B build -S "$pkgname-${pkgver}" \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX='/usr' \
        -DENABLE_KERNING=OFF \
        -DTFDN_ENABLE_WARN_ERROR=OFF \
        -DENABLE_FRIBIDI_BUILD=OFF \
        -DENABLE_HARFBUZZ_MINIMAL=OFF \
        -Wno-dev
    make -C build
}

package() {
    install -Dm644 $pkgname-$pkgver/LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

    cd build
    make DESTDIR="$pkgdir" install
}

sha256sums=('b67b0c0e95c221f5afcd0f4d81c1130401adbbdfc802761bbf012e478b720767')