# Copyright (C) 2020 Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
# This program is free software: you can redistribute it and/or modify
# it under the terms of the CC0 1.0 License.
# Maintainers: Parabola hackers <dev@lists.parabola.nu>
# Contributor: wael <wael@waelk.tech>
_libreboot_pkgver=20211122
pkgname=coreboot-util
pkgrel=1
pkgver=4.15+${_libreboot_pkgver}
pkgdesc="Misc. utils from the Coreboot project."
url="https://coreboot.org/"
arch=('x86_64' 'i686' 'armv7h')
license=('GPL2')
makedepends=('pciutils')

# According to Leah Rowe (lead Libreboot developer) we should only use mirrors as the
# official rsync server is limited in bandwidth.
_mirror="https://mirrors.mit.edu/libreboot/"
source=("${_mirror}/testing/${_libreboot_pkgver}/libreboot-${_libreboot_pkgver}_src.tar.xz"
	"${_mirror}/testing/${_libreboot_pkgver}/libreboot-${_libreboot_pkgver}_src.tar.xz.sig")
sha256sums=('e8a610e51e668c34627a6d9c048c554592fd2c2ab4dbcad83c85c06d132e5ad1'
            '4442fc225383e1edf8f45e1aecba81868ae43db19978f15c17828389364c0434')
sha512sums=('3eac75b33bc6d2874c3ca1ad2392db7287992cf91d37879bb3244dbd6716bc7ffa3f8d31e15d821899e91a55b6fe665d918bea4e9da92e5e98345e9bcbe1bb95'
            '3a532ecef550ef27b723845544e91ff6b13ed6f2f1188d40fdeb7b3c416be619ff58103c3b01cd52ff88c28df6d419d2113b92d0b8ba36d1a74cfc16f70e0e63')
validpgpkeys=('98CCDDF8E56047F475C044BDD0C62464FA8B4856') # Leah Rowe <info@minifree.org>

prepare() {
	cd "$srcdir/libreboot-${_libreboot_pkgver}_src/coreboot/default/util/ectool/"
	sed 's#/sbin#/bin#' -i Makefile
	cd "$srcdir/libreboot-${_libreboot_pkgver}_src/coreboot/default/util/nvramtool/"
	sed 's#/sbin#/bin#' -i Makefile
	cd "$srcdir/libreboot-${_libreboot_pkgver}_src/coreboot/default/util/superiotool/"
	sed 's#/sbin#/bin#' -i Makefile
	cd "$srcdir/libreboot-${_libreboot_pkgver}_src/coreboot/default/util/bucts/"
	sed 's#/sbin#/bin#' -i Makefile
}

build() {
	# Get to the directory.
	cd "$srcdir/libreboot-${_libreboot_pkgver}_src/coreboot/default/util/"
	# Build ECtool.
	make -C ectool
	# Build nvramtool.
	make -C nvramtool
	# Build superiotool.
	make -C superiotool
	# Build bucts.
	make -C bucts
}

package() {
	# Get to the directory.
	cd "$srcdir/libreboot-${_libreboot_pkgver}_src/coreboot/default/util/"

	# Install ECtool.
	install -Dm755 ectool/ectool "${pkgdir}"/usr/bin/ectool
	# Install nvramtool.
	install -Dm755 nvramtool/nvramtool "${pkgdir}"/usr/bin/nvramtool
	# Install superiotool.
	install -Dm755 superiotool/superiotool "${pkgdir}"/usr/bin/superiotool
	# Install bucts.
	install -Dm755 bucts/bucts "${pkgdir}"/usr/bin/bucts
}