# Maintainer (arch): Antonio Rojas <arojas@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Zuf <kontakt.zuf@gmail.com>
# Contributor: Darwin Bautista <djclue917@gmail.com>
# Contributor: Gustavo Alvarez <sl1pkn07@gmail.com>
# Contributor: Morris Zuss <morris@vlen.org>


# parabola changes and rationale:
# - arch package links to qt5-webengine
# - no changes necessary - simply rebuild without qt5-webengine in the environment


pkgname=kdenlive
pkgver=22.04.0
pkgrel=1
pkgrel+=.parabola1
pkgdesc='A non-linear video editor for Linux using the MLT video framework'
arch=(x86_64 i686)
url='https://apps.kde.org/kdenlive/'
license=(GPL)
groups=(kde-applications kde-multimedia)
depends=(kfilemetadata knewstuff knotifyconfig mlt purpose python qt5-networkauth rttr)
makedepends=(cmake extra-cmake-modules kdoctools v4l-utils)
optdepends=('ffmpeg: for FFmpeg plugin'
            'cdrtools: for creation of DVD ISO images'
            'dvdauthor: for creation of DVD'
            'dvgrab: for firewire capture'
            'recordmydesktop: for screen capture'
            'xine-ui: for DVD preview'
            'vlc: for DVD preview'
            'opencv: for motion tracking'
            'plasma-desktop: theme configuration'
            'opentimelineio: timeline export/import')
source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
sha256sums=('66147b2f1a2cf6f05eda15e4cc3e9d9b126d2dbcc187ecc6d78dea2c7b2c6d79'
            '3d14df1fbe075f0995d45c0a54a63b33d9805d4ce86b4172c6b72ad7b128a1a8')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>

build() {
  cmake -B build -S $pkgname-$pkgver \
    -DBUILD_TESTING=OFF \
    -DCRASH_AUTO_TEST=ON
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}