# Maintainer (arch): Sven-Hendrik Haase <svenstaro@gmail.com>
# Contributor: John Sowiak <john@archlinux.org>
# Contributor: tobias <tobias@archlinux.org>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: bill-auger <bill-auger@programmer.net>

# parabola changes and rationale:
# - removed support for non-free CUDA and optix
# - set OS type string to GNU/Linux-libre

pkgname=blender
pkgver=3.1.2
pkgrel=1
pkgrel+=.parabola1
_pythonver_x86_64=3.10
eval "_python_ver=\$_pythonver_${CARCH}"
pkgdesc="A fully integrated 3D graphics creation suite"
pkgdesc+=", without non-free CUDA or OptiX support"
arch=('x86_64')
license=('GPL')
url="https://www.blender.org"
depends=('alembic' 'boost-libs' 'draco' 'embree' 'ffmpeg' 'fftw' 'freetype2' 'glew'
         'hicolor-icon-theme' 'jack' 'jemalloc' 'libharu' 'libpng' 
	 'libsndfile' 'libspnav' 'libtiff' 'log4cplus' 'openal' 'opencollada'
	 'opencolorio' 'openexr' 'openimagedenoise' 'openimageio' 'openjpeg2'
	 'openshadinglanguage' 'opensubdiv' 'openvdb' 'openxr' 'potrace'
	 'ptex' 'python' 'python-numpy' 'sdl2')
makedepends=('boost' 'cmake' 'git' 'llvm' 'mesa' 'ninja')
options=(!strip)
source=("git+https://git.blender.org/blender.git#tag=v$pkgver"
        "git+https://git.blender.org/blender-addons.git"
        "git+https://git.blender.org/blender-addons-contrib.git"
        "git+https://git.blender.org/blender-translations.git"
        "git+https://git.blender.org/blender-dev-tools.git"
	"remove-cuda-optix-metal.patch"
	"force-draco1.patch"
	"force-draco2.patch")
sha512sums=('SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
	    'bea4f211c33dbc629cedb46293433c1a6c776a7dcf2bffd32b6164b0e81220b5aeb7f7359d8be2645b3dd54614a75212fbfed2664a80a4576ddd3e9f0fd0f8ea'
	    'e239da4f3906f1b54265435181cf770bae3d269c8d915df9a73861e6ee71ec70bf2339426e7c81a91e5a567273b3b3742d7a99feefd3398d821b26e1ff3a56d0'
	    '527ab66e5eace777de0043c1ca5787a488f6471450ce67fd6d08137ad0ef56177bc0c17696f30a5fca23fa55d8ca9c3f30cb7b17550dba2dbd8e89ca0b361990')

prepare() {
  cd "$pkgname"

  git submodule init
  git config submodule."release/scripts/addons".url "${srcdir}/blender-addons"
  git config submodule."release/scripts/addons_contrib".url "${srcdir}/blender-addons-contrib"
  git config submodule."release/datafiles/locale".url "${srcdir}/blender-translations"
  git config submodule."source/tools".url "${srcdir}/blender-dev-tools"
  git submodule update
  git submodule foreach git checkout v${pkgver}

  # set OS type string
  sed -i 's|BUILD_PLATFORM;|"GNU/Linux-libre";|' 'source/creator/buildinfo.c'

  # Libre patches
  # Removes any possible way to enable proprietary implementations
  patch -p1 < "$srcdir"/remove-cuda-optix-metal.patch
  
  # Deletes CUDA/OptiX/Metal files
  rm -rf intern/cycles/device/cuda
  rm -rf intern/cycles/device/metal 
  rm -rf intern/cycles/device/optix
  rm -rf intern/cycles/kernel/device/cuda
  rm -rf intern/cycles/kernel/device/metal 
  rm -rf intern/cycles/kernel/device/optix

  # Configure Draco (See FS#73415)
  patch -p1 -i "$srcdir"/force-draco1.patch
  patch -p1 -d release/scripts/addons -i "$srcdir"/force-draco2.patch

}

build() {
  cd "$pkgname"

  # Libre Changes
  local _extra_opts=( -DWITH_CYCLES_DEVICE_CUDA=OFF   \
                      -DWITH_CYCLES_DEVICE_OPTIX=OFF  )

  local PYTHON_VER=${_python_ver}

  cmake . \
    -Bbuild \
    -GNinja \
    -Cbuild_files/cmake/config/blender_release.cmake \
    ${_extra_opts[@]} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DWITH_INSTALL_PORTABLE=OFF \
    -DWITH_PYTHON_INSTALL=OFF \
    -DPYTHON_VERSION=$PYTHON_VER \
    -DPYTHON_LIBPATH=/usr/lib \
    -DPYTHON_LIBRARY=python$PYTHON_VER \
    -DPYTHON_INCLUDE_DIRS=/usr/include/python$PYTHON_VER \
    -DCMAKE_CXX_FLAGS="-I /usr/include/python$PYTHON_VER"
  ninja -C build
}

package() {
  cd "$pkgname"

  DESTDIR="${pkgdir}" ninja -C build install
  install -Dm755 release/bin/blender-softwaregl "${pkgdir}/usr/bin/blender-softwaregl"
  python -m compileall "${pkgdir}/usr/share/blender"
  python -O -m compileall "${pkgdir}/usr/share/blender"

  install -Dm644 release/freedesktop/org.blender.Blender.appdata.xml "${pkgdir}/usr/share/metainfo/org.blender.Blender.appdata.xml"

  # Manually install additional scripts (See FS#69351)
  cp -r release/scripts/addons_contrib/* "${pkgdir}"/usr/share/blender/3*/scripts/addons_contrib/

  # Manually install draco bindings (See FS#73415)
  mkdir -p "${pkgdir}"/usr/lib/python3.10/
  mv "${pkgdir}"/usr/share/blender/3*/python/lib/* "${pkgdir}"/usr/lib/
  rm -r "${pkgdir}"/usr/share/blender/3*/python
}