# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Santiago Torres-Arias <santiago[at]archlinux[dot]org>
# Contributor: Aaron McDaniel (mcd1992) <'aur' at the domain 'fgthou.se'>

# Parabola changes and rationale:
#   - Remove qt5-engine dependency with compile flag
#     CUTTER_ENABLE_QTWEBENGINE=false

pkgname=radare2-cutter
_gitcommit=b4535227cf1ebfb94da40c950215512acbcbb9bf
pkgver=1.9.0
epoch=1
pkgrel=2
pkgrel+=.par1
pkgdesc='Qt and C++ GUI for radare2 reverse engineering framework'
pkgdesc+=', without nonfree qt5-webengine dependency'
url='https://github.com/radareorg/cutter'
arch=('x86_64')
arch+=(i686 armv7h)
license=('GPL3')
depends=('radare2' 'capstone' 'qt5-base' 'qt5-svg' 'icu' 'python' 'jupyter'
         'pyside2' 'shiboken2' 'python-shiboken2')
makedepends=('git' 'cmake')
source=(${pkgname}::"git+https://github.com/radareorg/cutter#commit=${_gitcommit}")
sha512sums=('SKIP')

pkgver() {
  cd ${pkgname}
  git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  mkdir -p ${pkgname}/build
  cd ${pkgname}/build
  qmake ../src/Cutter.pro \
    CUTTER_ENABLE_PYTHON=true \
    CUTTER_ENABLE_PYTHON_BINDINGS=true \
    CUTTER_USE_BUNDLED_RADARE2=false \
    CUTTER_ENABLE_QTWEBENGINE=false
  make
}

package() {
  cd ${pkgname}
  install -Dm 755 build/Cutter -t "${pkgdir}/usr/bin"
  install -Dm 644 src/org.radare.Cutter.desktop -t "${pkgdir}/usr/share/applications"
  install -Dm 644 src/img/cutter.svg -t "${pkgdir}/usr/share/icons/hicolor/scalable/apps"
  install -d "${pkgdir}/usr/share/doc/${pkgname}"
  cp -a docs/* "${pkgdir}/usr/share/doc/${pkgname}"
}

# vim: ts=2 sw=2 et: