# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Contributor: sseneca <sseneca@ssene.ca>
# Maintainer: Andreas Grapentin <andreas@grapentin.org>

# rational for inclusion in libre:
#  - removed support for not freedom-respecting search engines

pkgname=kio
pkgver=5.65.0
pkgrel=1
pkgrel+=.parabola1
pkgdesc='Resource and network access abstraction'
pkgdesc+=', without non-privacy search engines'
arch=(x86_64)
arch+=(i686 armv7h)
url='https://community.kde.org/Frameworks'
license=(LGPL)
depends=(solid kjobwidgets kbookmarks libxslt kwallet ktextwidgets desktop-file-utils)
makedepends=(extra-cmake-modules kdoctools doxygen qt5-tools qt5-doc)
optdepends=('kio-extras: extra protocols support (sftp, fish and more)' 'kdoctools: for the help kioslave'
            'knetattach: to add new kio-remote entries')
groups=(kf5)
source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/$pkgname-$pkgver.tar.xz"{,.sig})
source+=("duckduckgo_html.desktop" "duckduckgo_lite.desktop")
sha256sums=('7d3cc0c82e83c082b424a2fe4c796c4c46f233ccd565775babbf6b434fce851b'
            'SKIP'
            '31910ab7393e67609f15e04a57f6406f63e6dae58b01bce0787741bc5958f292'
            '40466a9dad7075f2525e9e024720da7d7b49a22892b6fca8b81cc0e6408d2f7d')
validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure@kde.org>

prepare() {
  mkdir -p build

  # Removing non-privacy search providers
  cd $pkgname-$pkgver
  rm -v src/urifilters/ikws/searchproviders/{7digital,acronym,amazon{,_mp3},amg,backports,baidu,bing,cia,dbug,deb,duckduckgo{,_info,_shopping},facebook,ecosia,feedster,flickr,flickrcc,google,google_advanced,google_code,google_groups,google_images,google_lucky,google_maps,google_movie,google_news,google_shopping,imdb,jamendo,jeeves,magnatune,metacrawler,msdn,nl-telephone,nl-teletekst,python,rpmfind,tvtome,uspto,vimeo,voila,yahoo,yahoo_image,yahoo_local,yahoo_shopping,yahoo_video,youtube}.desktop

  # Adding DuckDuckGo HTML
  cp -v "$srcdir/duckduckgo_html.desktop" src/urifilters/ikws/searchproviders
  # Adding DuckDuckGo Lite
  cp -v "$srcdir/duckduckgo_lite.desktop" src/urifilters/ikws/searchproviders
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DCMAKE_INSTALL_LIBEXECDIR=lib \
    -DBUILD_TESTING=OFF \
    -DBUILD_QCH=ON
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}