# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Gustavo Alvarez <sl1pkn07@gmail.com>
# Contributor (Arch): Balló György <ballogyor+arch at gmail dot com>

pkgbase=marble
pkgname=(marble-common)
pkgver=20.04.1
pkgrel=1
pkgrel+=.parabola1
pkgdesc="Desktop Globe"
arch=(x86_64)
arch+=(i686 armv7h)
url="https://www.kde.org/applications/system/marble"
license=(GPL)
makedepends=(extra-cmake-modules gpsd kdoctools knewstuff kparts krunner libwlocate phonon-qt5
             plasma-workspace qt5-serialport qt5-tools qt5-webkit shapelib)
source=("https://download.kde.org/stable/release-service/$pkgver/src/$pkgbase-$pkgver.tar.xz"{,.sig})
sha256sums=('28cdf7161e8f3a2f00fd35cc4a384e29e7875c7177c27ff6d5dd8f8f53bcaa67'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../$pkgbase-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DCMAKE_INSTALL_SYSCONFDIR=/etc \
    -DQT_PLUGINS_DIR=lib/qt/plugins \
    -DBUILD_TESTING=OFF \
    -DBUILD_MARBLE_EXAMPLES=OFF \
    -DBUILD_MARBLE_TESTS=OFF \
    -DMOBILE=OFF
  make
}

package_marble-common() {
  pkgdesc='Common libraries and plugins for Marble'
  depends=(qt5-svg qt5-webkit phonon-qt5 desktop-file-utils)
  optdepends=('gpsd: GPS based geolocation'
              'libwlocate: WLAN based geolocation'
              'qt5-serialport: APRS plugin'
              'shapelib: SHP plugin')

  cd build
  make DESTDIR="$pkgdir" install
  rm -rf "$pkgdir"/usr/share/{config.kcfg,kxmlgui5,metainfo,plasma} \
         "$pkgdir"/usr/bin \
         "$pkgdir"/etc \
         "$pkgdir"/usr/lib/qt/{qml,plugins/*.so} \
         "$pkgdir"/usr/share/applications/{marble_geo.desktop,marble_worldwind.desktop,org.kde.marble*.desktop} \
         "$pkgdir"/usr/share/kservices5/{marble_part.desktop,plasma*} \
         "$pkgdir"/usr/share/locale/*/LC_MESSAGES/*.mo
}